안녕하세요..

우선 그 네개의 TMemo 콘트롤의 크기가 동일하다는 가정하에 아래 예제를 따라해보세요..

저는 두개로만 구현해보았는데, Memo3, Memo4 를 DoSync 프로시저 안에 기술해 주시면 되겠지요..

원리는 기준이 되는 Memo 콘트롤의 메시지를 가로채서 동일한 메시지를 다른 Memo 콘트롤에도 발생시키는 것입니다.

이런것을 '서브클래싱'이라고 부릅니다.. 한번 따라해 보시면 이해 되실거예요..

그럼 즐거운 프로그래밍 하시구요..


unit Unit4;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;

type
TForm4 = class(TForm)
Memo1: TMemo;
Memo2: TMemo;
Memo3: TMemo;
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
FOldMemoWndProc: TWndMethod;
procedure NewMemoWndProc(var M: TMessage);
procedure DoSync(Msg: Cardinal; wParam: Integer; lParam: Integer);
public
{ Public declarations }
end;

var
Form4: TForm4;
OldWindowProc : Pointer;

implementation

{$R *.dfm}

procedure TForm4.DoSync(Msg: Cardinal; wParam: Integer; lParam: Integer);
begin
Memo2.Perform(Msg, Wparam, Lparam);
end;

procedure TForm4.NewMemoWndProc(var M: TMessage);
begin
case M.Msg of
WM_VSCROLL, WM_HSCROLL, WM_MOUSEWHEEL :
DoSync(M.Msg, M.WParam, M.LParam);
end;
FOldMemoWndProc(M);
end;

procedure TForm4.FormCreate(Sender: TObject);
begin
FOldMemoWndProc := Memo1.WindowProc;
Memo1.WindowProc := NewMemoWndProc;
end;


end.

초보가 이해하긴 대단히 어려운 내용같습니다..

하여간, 좋은 답변주신데 대해 , 저의 감사의 마음을 전합니다.

고맙습니다.

FOldMemWnProc(M) <---- 이건 내장 프로시져인가요?

어떤 내용인지 확인하려면, 어디를 찾아봐야합니까?

윈도우프로시져???

조금 설명을 달아 보겠습니다..

음.. FOldMemoWndProc 는 함수포인터라고 하는건데.. 일종의 변수라고 보면 됩니다.

TWndMethod 를 따라가보시면 아래처럼 생겨먹었습니다.
TWndMethod = procedure(var Message: TMessage) of object;

TMemo 같은 콘트롤들은 메시지를 처리하는 프로시저를 가지고 있습니다..
델파이에는 그것들을 프로퍼티화 시켜두었습니다.
그것이 바로 WndProc 입니다.
TControl 의 WndProc 를 보면 아래처럼 생겼습니다.
아래 내용을 다 이해하실 필요는 없고요.. 그냥 이렇게 생겼구나..하고 넘어 가시면 됩니다.


procedure TControl.WndProc(var Message: TMessage);
var
Form: TCustomForm;
KeyState: TKeyboardState;
WheelMsg: TCMMouseWheel;
Panned: Boolean;
{$IF DEFINED(CLR)}
LMsg: TMessage;
{$IFEND}
begin
if (csDesigning in ComponentState) then
begin
Form := GetParentForm(Self, False);
if (Form <> nil) and (Form.Designer <> nil) and
Form.Designer.IsDesignMsg(Self, Message) then Exit
end;
if (Message.Msg >= WM_KEYFIRST) and (Message.Msg <= WM_KEYLAST) then
begin
Form := GetParentForm(Self);
if (Form <> nil) and Form.WantChildKey(Self, Message) then Exit;
end
else if (Message.Msg >= WM_MOUSEFIRST) and (Message.Msg <= WM_MOUSELAST) then
begin
if not (csDoubleClicks in ControlStyle) then
case Message.Msg of
WM_LBUTTONDBLCLK, WM_RBUTTONDBLCLK, WM_MBUTTONDBLCLK:
Dec(Message.Msg, WM_LBUTTONDBLCLK - WM_LBUTTONDOWN);
end;
case Message.Msg of
WM_MOUSEMOVE: Application.HintMouseMessage(Self, Message);
WM_MBUTTONDOWN:
begin
if (csPannable in ControlStyle) and
(ControlState * [csDestroyingHandle, csPanning] = []) and
not Mouse.IsDragging then
begin
Mouse.CreatePanningWindow;
Panned := False;
if Assigned(Mouse.PanningWindow) then
begin
if Self is TWinControl then
Panned := Mouse.PanningWindow.StartPanning(TWinControl(Self).Handle, Self)
else if Parent <> nil then
Panned := Mouse.PanningWindow.StartPanning(Parent.Handle, Self)
else
begin
Form := GetParentForm(Self, False);
if Form <> nil then
Panned := Mouse.PanningWindow.StartPanning(Form.Handle, Self);
end;
end;
if Panned then
begin
Message.Result := 1;
Application.HideHint;
end
else if Assigned(Mouse.PanningWindow) then
Mouse.PanningWindow := nil;
end;
end;
WM_LBUTTONDOWN, WM_LBUTTONDBLCLK:
begin
if FDragMode = dmAutomatic then
begin
BeginAutoDrag;
Exit;
end;
Include(FControlState, csLButtonDown);
end;
WM_LBUTTONUP:
Exclude(FControlState, csLButtonDown);
else
with Mouse do
if WheelPresent and (RegWheelMessage <> 0) and
(Integer(Message.Msg) = Integer(RegWheelMessage)) then
begin
GetKeyboardState(KeyState);
{$IF DEFINED(CLR)}
WheelMsg := TCMMouseWheel.Create;
{$IFEND}
with WheelMsg do
begin
Msg := Message.Msg;
ShiftState := KeyboardStateToShiftState(KeyState);
WheelDelta := Message.WParam;
Pos := SmallPoint(Message.LParam and $FFFF, Message.LParam shr 16);
end;
{$IF DEFINED(CLR)}
LMsg := WheelMsg.OriginalMessage;
MouseWheelHandler(LMsg);
{$ELSE}
MouseWheelHandler(TMessage(WheelMsg));
{$IFEND}
Exit;
end;
end;
end
else if Message.Msg = CM_VISIBLECHANGED then
with Message do
SendDockNotification(Msg, WParam, LParam);
Dispatch(Message);
end;


Memo1.WindowProc 를 임시로 선언한 함수포인터 변수 FOldMemoWndProc 에 기억해두고,
Memo1.WindowProc 는 NewMemoWndProc 로 대치시킵니다.

그렇게 되면 Memo1 에서 발생하는 메시지는 이제 NewMemoWndProc 에서 처리할 수 있게 됩니다.
또한 NewMemoWndProc 에서 메시지를 처리하고 나서 기존의 메시지도 처리하도록 FOldMemoWndProc(M) 을 호출도 해주는 것이지요..

Memo 에서 스크롤이 발생할 수 있는경우가 크게 세가지가 있겠지요..

WM_VSCROLL, WM_HSCROLL, WM_MOUSEWHEEL <-- 이 메시지들인데요..

이 메시지들이 발생했을때.. 사용자 정의 함수인 DoSync()를 호출해서..

발생한 메시지와 동일한 메시지들을 다른 Memo 컨트롤에서도 발생시켜 주는것입니다.

그러면 다른 메모콘트롤들도 스크롤때 발생하는 동일한 동작을 하게 되겠지요..

procedure TForm4.DoSync(Msg: Cardinal; wParam: Integer; lParam: Integer);
begin
Memo2.Perform(Msg, Wparam, Lparam);
//이곳에 원하시는 Memo 컴포넌트들을 아래처럼 기술해 주시면 되겠지요..
//Memo3.Perform(Msg, Wparam, Lparam);
//Memo4.Perform(Msg, Wparam, Lparam);
end;

아..말주변이 없어 설명드리기 되게 힘드네요..

아뭍든 핵심원리는 위와 같습니다..

그럼.. 즐거운 프로그래밍하세요..

어렴풋이 이해할수있게되었습니다. 정말 감사합니다.그런데
실제로 코드를 입력해보니 아래와 같은 오류가 발생하는데,
무엇이 잘못되었는지요?
]
Dosync 를 호출하는 과정에서
DBmemo3.Perform(Msg,Wparam,Lparam);

여기서 '(' expected but ')' found 라는 오류 메시지가 뜹니다.
어떻게 수정해야하는지요?

동원님.. 위에러만 봐서는 상황을 알 수 없고요...
에러나는 부분의 함수부분만이라도 떼서 올려보세요..
혹은 전체코드를 올려도 좋고요..

님께서 올려주신대로 새로 코드를 써서 만들었더니 잘 됩니다.
그런데 문제는 다른데 있었던것 같습니다.

Memo 컴포넌트에 대해서는 위에 올려주신 것이 잘 동작합니다
그런데
똑같은 상황을
Memo 컴포넌트가 아닌 DBmemo 컴포넌트를 썼더니 안됩니다.

어떻게 고쳐야할지요?

Memo2.Perform(Msg, Wparam, Lparam);

이부분에서 Memo2 를 DBmemo2.Perform 으로 바꿨더니 안됩니다.

그냥 memo component에서 스크롤 되는 것을 인터셉트하는것과
dbmemo component 에서 사용하는 함수가 다른가요??
이해가 잘 안됩니다.(느낌으로는 같을것 같은데요..^^)
=====================================================
상세하고 지속적인 답변에 거듭 감사를 드립니다.

꾸벅

참고] 제가 만든 코드를 올리려고 해도, 너무 길어서
올릴수가 없군요.(^_^)