안녕하세요. 최용일입니다.

걍 for문 몇번이면 해결됩니다. 실질적으로 경우의수 만드는데 쓰이는 for문은 딱 2번이네요...

<!--CodeS-->
function GetNumberOfCaseCount(const Source: array of string): Integer;
var
  Index: Integer;
begin
  Result := Length(Source[0]);
  for Index := 1 to High(Source) do
    Result := Result * Length(Source[Index]);
end;

procedure GetNumberOfCaseList(const Source: array of string;
  var List: array of string);
var
  Index, Count: Integer;
  PermutationCount, PermutationSize: Integer;
  RepeatCount, SourceLength, SourceIndex: Integer;
begin
  PermutationSize := Length(Source);
  PermutationCount := Length(List);
  for Index := 0 to High(List) do
    SetLength(List[Index], PermutationSize); // for Better Performance...

  RepeatCount := PermutationCount;
  for Index := 0 to High(Source) do
  begin
    SourceLength := Length(Source[Index]);
    RepeatCount := RepeatCount div SourceLength;
    for Count := 0 to PermutationCount - 1 do
    begin
      SourceIndex := ((Count div RepeatCount) mod SourceLength);
      List[Count][Index+1] := Source[Index][SourceIndex+1];
      // Low Performance...
      // List[Count] := List[Count] + Source[Index][SourceIndex+1];
    end;
  end;
end;


// Call...
procedure TForm1.Button1Click(Sender: TObject);
var
  Index: Integer;
  Str1, Str2, Str3: string;
  StaticArray: array[0..1] of string;
  DynamicArray: array of string;
  PermutationCount: Integer;
  PermutationList: array of string;
begin
  Memo1.Lines.Clear;

  // Ex 1
  NumberOfCaseCount := GetNumberOfCaseCount(['abc', '123', 'XYZ', '45678']);
  SetLength(NumberOfCaseList, NumberOfCaseCount);
  GetNumberOfCaseList(['abc', '123', 'XYZ', '45678'], NumberOfCaseList);

  for Index := 0 to High(NumberOfCaseList) do
    Memo1.Lines.Add(NumberOfCaseList[Index]);

  // Ex 2
  Str1 := 'abc';
  Str2 := '123';
  Str3 := 'XYZ';
  NumberOfCaseCount := GetNumberOfCaseCount([Str1, Str2, Str3]);
  SetLength(NumberOfCaseList, NumberOfCaseCount);
  GetNumberOfCaseList([Str1, Str2, Str3], NumberOfCaseList);

  for Index := 0 to High(NumberOfCaseList) do
    Memo1.Lines.Add(NumberOfCaseList[Index]);

  // Ex 3
  StaticArray[0] := 'abc';
  StaticArray[1] := '123';
  NumberOfCaseCount := GetNumberOfCaseCount(StaticArray);
  SetLength(NumberOfCaseList, NumberOfCaseCount);
  GetNumberOfCaseList(StaticArray, NumberOfCaseList);

  for Index := 0 to High(NumberOfCaseList) do
    Memo1.Lines.Add(NumberOfCaseList[Index]);

  // Ex 4
  SetLength(DynamicArray, 3);
  DynamicArray[0] := 'abc';
  DynamicArray[1] := '123';
  DynamicArray[2] := 'XYZ';
  NumberOfCaseCount := GetNumberOfCaseCount(DynamicArray);
  SetLength(NumberOfCaseList, NumberOfCaseCount);
  GetNumberOfCaseList(DynamicArray, NumberOfCaseList);

  for Index := 0 to High(NumberOfCaseList) do
    Memo1.Lines.Add(NumberOfCaseList[Index]);
end;
<!--CodeE-->

에러처리나 쉼표처리하는 것은 소스보시고 수정해서 쓰세요...

^^ 항상 즐코하세요...

감사합니다.