안녕하세요. 최용일입니다.



소스 입니다. (델파이5)



// 메세지 박스를 보이는 프로그램 유닛

unit MsgForm_Unit;



interface



uses

Windows, Messages, Classes, Forms, StdCtrls, Controls;



type

TMsgForm = class(TForm)

MsgButton: TButton;

Label1: TLabel;

procedure MsgButtonClick(Sender: TObject);

end;



var

MsgForm: TMsgForm;



implementation



{$R *.DFM}



procedure TMsgForm.MsgButtonClick(Sender: TObject);

begin

Application.MessageBox('메세지 박스입니다.', 'MsgBox', id_OK);

end;



end.



// 메세지 박스를 보이는 프로그램 유닛의 폼

object MsgForm: TMsgForm

Left = 447

Top = 24

Width = 276

Height = 96

Caption = 'MsgForm'

Color = clBtnFace

Font.Charset = HANGEUL_CHARSET

Font.Color = clWindowText

Font.Height = -12

Font.Name = '굴림'

Font.Style = []

OldCreateOrder = False

PixelsPerInch = 96

TextHeight = 12

object Label1: TLabel

Left = 14

Top = 12

Width = 240

Height = 12

Caption = '아래의 버튼을 누르면 메세지 박스가 뜹니다.'

end

object MsgButton: TButton

Left = 96

Top = 36

Width = 75

Height = 25

Caption = 'MsgButton'

TabOrder = 0

OnClick = MsgButtonClick

end

end



// 메세지 박스를 찾는 프로그램 유닛

unit FindForm_Unit;



interface



uses

Windows, Messages, SysUtils, Classes, Forms, ExtCtrls, StdCtrls, Controls;



type

TForm1 = class(TForm)

Timer1: TTimer;

Label1: TLabel;

CheckBox1: TCheckBox;

Button1: TButton;

procedure Timer1Timer(Sender: TObject);

procedure CheckBox1Click(Sender: TObject);

procedure Button1Click(Sender: TObject);

end;



var

Form1: TForm1;



implementation



{$R *.DFM}



procedure TForm1.Timer1Timer(Sender: TObject);

var

DialogWnd, ButtonWnd: HWND;

begin

// 메세지 박스 찾기...

DialogWnd := FindWindow('#32770', 'MsgBox');

if DialogWnd <> 0 then

begin

// 메세지 박스의 버튼 핸들을 찾기

ButtonWnd := FindWindowEx(DialogWnd, 0, 'Button', '확인');



// 버튼에 클릭메세지를 보내 메세지 박스를 닫기

if ButtonWnd <> 0 then

begin

SendMessage(ButtonWnd, WM_LBUTTONDOWN, 0, 0);

SendMessage(ButtonWnd, WM_LBUTTONUP, 0, 0);

end;



end;

end;



procedure TForm1.CheckBox1Click(Sender: TObject);

begin

Timer1.Enabled := CheckBox1.Checked;

end;



procedure TForm1.Button1Click(Sender: TObject);

var

Path: string;

begin

Path := ExtractFilePath(Application.ExeName);

WinExec(PChar(Path + 'MsgForm_Prj.exe'), SW_SHOWDEFAULT);

end;



end.



// 메세지 박스를 찾는 프로그램 유닛의 폼

object Form1: TForm1

Left = 191

Top = 23

Width = 224

Height = 149

Caption = 'Form1'

Color = clBtnFace

Font.Charset = HANGEUL_CHARSET

Font.Color = clWindowText

Font.Height = -12

Font.Name = '굴림체'

Font.Style = []

OldCreateOrder = False

PixelsPerInch = 96

TextHeight = 12

object Label1: TLabel

Left = 27

Top = 16

Width = 162

Height = 12

Caption = '메세지 박스를 먼저 띄우세요'

end

object CheckBox1: TCheckBox

Left = 59

Top = 48

Width = 97

Height = 17

Caption = '타이머 가동'

Checked = True

State = cbChecked

TabOrder = 0

OnClick = CheckBox1Click

end

object Button1: TButton

Left = 27

Top = 88

Width = 161

Height = 25

Caption = '메세지 프로그램 실행하기'

TabOrder = 1

OnClick = Button1Click

end

object Timer1: TTimer

Interval = 100

OnTimer = Timer1Timer

Left = 172

Top = 44

end

end



^^ 항상 즐코하세요.



안희준 wrote:

> 제가 무엇을 잘못했는지 모르겠지만 예제를 보면 이해가 빠를것 같군요..

>

> 다른 프로그램의 버튼을 누른후 나오는 메세지박스를 찾아 닫는겁니다..

>

> 제가 코딩하는 부분에 A 버튼을 누르면 다른 프로그램의 [검색] 버튼을 눌러

>

> 메세지박스가 뜨면 닫는거지요..

>

> 그럼.........잘된다고 하시니 제가 질문하게 해결 가능한 얘기이군요...^^

>

> 실력이 딸려서리.....암튼 부탁드려요...^^

>

> 이곳을 자주 이용하게 될것 같은 느낌이 듭니다.....하하..^^

안녕하세요. 최용일입니다.



저는 델파이 5를 씁니다. 실행 파일을 같이 보내니까 먼저 실행해 보세요.



한메일이 맛이 갔나? 갑자기 파일 첨부가 않되네요... 아뭏든 보내드렸습니다.



^^ 항상 즐코하세요.



안희준 wrote:

> 제가 무엇을 잘못했는지 모르겠지만 예제를 보면 이해가 빠를것 같군요..

>

> 다른 프로그램의 버튼을 누른후 나오는 메세지박스를 찾아 닫는겁니다..

>

> 제가 코딩하는 부분에 A 버튼을 누르면 다른 프로그램의 [검색] 버튼을 눌러

>

> 메세지박스가 뜨면 닫는거지요..

>

> 그럼.........잘된다고 하시니 제가 질문하게 해결 가능한 얘기이군요...^^

>

> 실력이 딸려서리.....암튼 부탁드려요...^^

>

> 이곳을 자주 이용하게 될것 같은 느낌이 듭니다.....하하..^^