^^v

안녕하세요. ^^a

Edit에 서브클래스를 해서 WM_RBUTTONDOWN 메세지를 무시해 버리는방법으로 구현해봤습니다.

참고하세요.


unit uMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TMainForm = class(TForm)
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FEditInstance: Pointer;
    FDefEditProc: Pointer;
  public
    procedure EditWndProc(var Message: TMessage);
  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

procedure TMainForm.EditWndProc(var Message: TMessage);
begin
  with Message do
  begin
    case Msg of
      WM_RBUTTONDOWN: Exit;
    end;
    Result := CallWindowProc(FDefEditProc, Edit1.Handle, Msg, WParam, LParam);
  end;
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  FEditInstance := MakeObjectInstance(EditWndProc);
  FDefEditProc := Pointer(GetWindowLong(Edit1.Handle, GWL_WNDPROC));
  SetWindowLong(Edit1.Handle, GWL_WNDPROC, LongInt(FEditInstance));
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  SetWindowLong(Edit1.Handle, GWL_WNDPROC, Longint(FDefEditProc));
  FreeObjectInstance(FEditInstance);
end;

end.



그럼..20000.

흐 form 에서여.. PopupMenu1 을 올려 놓고 .. 물론 PopupMenu1에는 메뉴가 하나두 없습니다. 그리고는 edit의 PopupMenu 프로퍼티를  PopupMenu1
로 고칩니다.
키득.. 제가 보기에는 Ctrl+C Ctrl+V를 막는 질문 같은데..