안녕하세요~ 구창민입니다.

TEdit 는 오른쪽 정렬을 지원하지 않습니다.

아래의 컴포넌트를 등록하시고, 사용해보세요~

항상 즐거운 프로그래밍 하시구요~

unit AlignedEdit;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
Dialogs,
StdCtrls;

type
TAlignedEdit = class(TEdit)
private
   fAlignment: TAlignment;
   procedure SetAlignment(const Value: TAlignment);
   procedure WMGetDlgCode(var Message: TWMGetDlgCode); message
WM_GETDLGCODE;
   { Private declarations }
protected
   { Protected declarations }
   Procedure CreateParams( Var params: TCreateParams ); override;
public
   { Public declarations }
published
   { Published declarations }
   property Alignment: TAlignment read fAlignment write SetAlignment
     default taLeftJustify;
end;

procedure Register;

implementation

procedure Register;
begin
RegisterComponents('Sample', [TAlignedEdit]);
end;

{ TAlignedEdit }

procedure TAlignedEdit.CreateParams(var params: TCreateParams);
const
Styles : Array [TAlignment] of DWORD =
          (ES_LEFT, ES_RIGHT, ES_CENTER );
begin
inherited;
params.style := params.style or Styles[ Falignment ] or
                 ES_MULTILINE * Ord( FAlignment <> taLeftJustify);
end;

procedure TAlignedEdit.SetAlignment(const Value: TAlignment);
begin
If fAlignment <> Value Then Begin
   fAlignment := Value;
   RecreateWnd;
End;
end;

procedure TAlignedEdit.WMGetDlgCode(var Message: TWMGetDlgCode);
begin
inherited;
Message.Result := Message.Result and not DLGC_WANTALLKEYS;
end;

^^*